Nachdem sich das Kompilieren für die 0.81.8 etwas geändert hat und ich neulich auch das aktuelle JAVA 1.4.2_05 installiert habe und ich wieder die Pfade anpassen musste, hab ich mir kurzerhand ein kleines KIX-Script geschrieben.
Danke an Wingman für´s Mittesten.
Vielleicht kann´s ja einer brauchen.
Konstuktive Kritik und weitere Anregungen sind erwüscht.
Wer einen Bug findet, bitte posten.
Voraussetzung:
Das Script läuft ab X-Version 0.81.8 und nur unter NT-basierenden OS.
JAVA SDK 1.4.xxx muss installiert sein.
Installation:
Einfach das Tool in den PX-Ordner kopiern und starten.
Arbeitsweise:
- Das Tool frägt zuerst ab, ob der JAVA-SDK installiert ist ab und liest den Install-Pfad aus der Registry aus.
- Betreibssystemcheck.
- JavaCup.ico ins PX-Verzeichnis kopieren und umbenennen
- X kompilieren
- Möglichkeit Verknüpfungen im Programm-Menü, Quicklauch und auf dem Desktop anzulegen.
Script-Text (nähere Infos zu KIX gibt´s bei
http://www.kixtart.org)
Code: Alles auswählen
;Variablen
$px = $EXEPath ;Pfad zum PX-/Script-Verzeichnis
$build = $px + "\build\" ;Build-Verzeichnis im PX-Ordner
$jar = $px + "\ProjectX.jar" ;Pfad zur ProjectX.jar
$ico = $px + "\px.ico" ;Pfad zum PX-Icon
$pro = %ALLUSERSPROFILE% + "\Startmenü\Programme\ProjectX.lnk" ;Verknüfung im Programmm-Menü
$quick = %APPDATA% + "\Microsoft\Internet Explorer\Quick Launch\ProjectX.lnk" ;Verknüpfung Quicklaunch
$desk = %UserProfile% + "\Desktop\ProjectX.lnk" ;Desktopverknüpfung
$lnk = $px + "\ProjecX.lnk"
;Pfad zum Java SDK 1.4.xxx auslesen
$sdk = ReadValue("HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit\1.4", "JavaHome")
;JAVA-SDK Abfrage
If Exist($sdk) = 0
$=MessageBox("Java SDK 1.4.xxx ist nicht installiert", "SDK-Check", 16)
Exit
EndIf
;Betriebssystemabfrage
If @INWIN = 2
$=MessageBox("Fossile Betriebssysteme :-) werden derzeit nicht unterstützt", "OS-Check", 16)
Exit
EndIf
;Abfrage des Build-Ordners
If Exist ($build) = 0
MD $build
EndIf
;Java-Icon kopieren
If Exist ($ico) = 0
Copy $sdk + "\jre\javaws\JavaCup.ico" $ico
EndIf
;Alte ProjectX.jar löschen
Del $jar /c
;evtl. vorhandene Class-Dateien löschen
Del $build + "*.class" /c
;ProjectX kompilieren
CD $px
Shell $sdk + "\bin\javac.exe -O -classpath src -d build src\*.java"
Sleep 2
CD $px
Shell $sdk + "\bin\jar.exe cfvm ProjectX.jar MANIFEST.MF -C build ."
Sleep 2
;erzeugte Class-Dateien Class-Dateien löschen
Del $build + "*.class" /c
;Verknüpfungen erstellen
;Verknüpfung im PX-Verzeichnis anlegen
If Exist ($pro) = 1
Copy $pro $lnk
Else AddProgramItem($jar, "ProjectX", $ico, 0, $px + "\",0,0)
Move $pro $lnk
EndIf
;Programm-Menü
$Sel1 = MessageBox("Verknüpfung Im Programm-Menü erstellen?", "ProjectX kompilieren", 36)
If $Sel1 = 6
If Exist ($pro) = 0
Copy $lnk $pro
EndIf
EndIf
;Schnellstartleiste
$Sel2 = MessageBox("Verknüpfung in der Schnellstartleiste erstellen?", "ProjectX kompilieren", 36)
If $Sel2 = 6
If Exist ($quick) = 0
Copy $lnk $quick
EndIf
EndIf
;Desktop
$Sel3 = MessageBox("Verknüpfung auf dem Desktop erstellen?", "ProjectX kompilieren", 36)
If $Sel3 = 6
If Exist ($desk) = 0
Copy $lnk $desk
EndIf
EndIf
;Verknüpfung im PX-Verzeichnis löschen
Del $lnk
Exit
Die EXE wurde mit dem Kixscripts-Editor erstellt und beinhaltet neben dem eigentlichen Script die kix32.exe (v4.22).
http://people.freenet.de/schuftpinky/px_compile.rar